1# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
2# Contributor: Antonio Rojas <arojas@archlinux.org>
3# Contributor: Ronald van Haren <ronald.archlinux.org>
4# Contributor: Damir Perisa <damir.perisa@bluewin.ch>
5# Contributor: sebalis
6_base=Celestia
7pkgname=${_base,,}
8pkgver=1.6.4
9pkgrel=3
10pkgdesc="Real-time space simulation"
11arch=(x86_64)
12license=(GPL-2.0-or-later)
13url="https://${pkgname}project.space"
14depends=(gtk2 libtheora lua gtkglext freeglut libxmu glu libjpeg-turbo mesa)
15options=('!makeflags')
16source=(https://github.com/${_base}Project/${_base}/archive/${pkgver}/${_base}-${pkgver}.tar.gz
17  m4.patch::https://github.com/${_base}Project/${_base}/pull/2173.patch)
18sha512sums=('58f5e55bcb193f89202663a2af8dbb920fa5bd4e893c0ec1884488b238d459d91ffc750b6b7a71653bdbe9e79e88d785020f9b189df8fad750bea39bf995a91c'
19            'd9fe5c8d100c5eabeb177ad42a199b2591cc43cda3dd87cbc714e54654349da04c2bc76cfe3f2bf490b5e7f4b98dcc3aaf74b3a1921b50de3f1a67125f277ba1')
20
21prepare() {
22  cd ${_base}-${pkgver}
23  patch -p1 -i ../m4.patch
24  gettext_version="$( gettext --version | sed -ne '1 s/.* \([0-9]\+\.[0-9.]\+\)/\1/p; q' )"
25  test -n "$gettext_version" || { echo "Can't determine gettext version" >&2; return 1; }
26  sed -i "/AM_GNU_GETTEXT(/ a AM_GNU_GETTEXT_VERSION($gettext_version)" configure.ac
27}
28
29build() {
30  cd ${_base}-${pkgver}
31  autoreconf -fvi -I /usr/share/gettext/m4
32  ./configure --prefix=/usr \
33    --with-lua=/usr \
34    --datadir=/usr/share \
35    --with-gtk \
36    --disable-rpath \
37    --with-lua
38  make
39}
40
41package() {
42  cd ${_base}-${pkgver}
43  make DESTDIR="${pkgdir}" MKDIR_P='mkdir -p' install
44}
45